build.gradle

plugins {
    id 'java-library'
    id 'maven-publish'
    id 'io.papermc.paperweight.userdev' version '2.0.0-beta.19'
}

ext.majorVersion = 7
ext.minorVersion = 0
ext.minecraftVersion = "1.21.8"

java {
    toolchain.languageVersion = JavaLanguageVersion.of(21)
}

// Suppiled by Jenkins
ext.buildNumber = System.env.BUILD_NUMBER == null ? "x"                : "$System.env.BUILD_NUMBER"
ext.mavenDirectory = System.env.MAVEN_DIR == null ? "$projectDir/repo" : "$System.env.MAVEN_DIR"

// Version used for distribution. Different from maven repo
group = "cat.nyaa"
version = "$majorVersion.$minorVersion.$buildNumber"

// Base name for archives (Gradle 9 compatible)
base {
    archivesName = "Yasui-mc$minecraftVersion"
}

repositories {
    mavenCentral()
    maven { name 'PaperMC'; url 'https://repo.papermc.io/repository/maven-public/' }
}


dependencies {
    // Paper development bundle - includes API + NMS with Mojang mappings
    // Do NOT add Paper API separately - dev bundle includes it
    paperweight.paperDevBundle("$minecraftVersion-R0.1-SNAPSHOT")
    // ASM is required by the agent at runtime; bundle into the plugin jar
    implementation "org.ow2.asm:asm:9.7.1"
}

compileJava {
    options.compilerArgs += ["-Xlint:deprecation"]
    options.encoding = 'UTF-8'
}

// Reobfuscate for production - converts Mojang mappings to Spigot for server compatibility
assemble {
    dependsOn(reobfJar)
}

// publications
task sourcesJar(type: Jar) {
    from sourceSets.main.allJava
    archiveClassifier = 'sources'
}
jar {
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
    manifest {
        attributes(
            'Agent-Class': 'cat.nyaa.yasui.agent.YasuiAgent',
            'Can-Redefine-Classes': 'true',
            'Can-Retransform-Classes': 'true'
        )
    }
    from {
        configurations.runtimeClasspath.findAll { it.name.startsWith("asm-") }.collect { it.isDirectory() ? it : zipTree(it) }
    }
}
processResources { // modify version string
    filesMatching("**/plugin.yml") {
        expand 'version': project.version
    }
}
publishing {
    publications {
        mavenJava(MavenPublication) {
            artifact sourcesJar
            groupId "cat.nyaa"
            artifactId "yasui"
            version "$majorVersion.$minorVersion-SNAPSHOT"
            from components.java
        }
    }
    repositories {
        maven {
            url "${mavenDirectory}"
        }
    }
}